sql里怎么把一列的值合并成一个字符串？？？

--> 测试数据: #T

if object_id('tempdb.dbo.#T') is not null drop table #T

create table #T (A varchar(4),B varchar(5))

insert into #T

select 'pro1','qqqqq' union all

select 'pro1','wwwww' union all

select 'pro1','eeeee' union all

select 'pro2','rrrrr' union all

select 'pro2','ttttt' union all

select 'pro1','yyyyy' union all

select 'pro1','uuuuu'



--> 2000

declare @i int, @max int, @sql varchar(max)

select top 1 @i=1, @max=count(*) from #T group by A order by 2 desc

while @i<=@max

begin

	set @sql=isnull(@sql+'+max(case i when '+ltrim(@i)+' then '',''+','max(case i when '+ltrim(@i)+' then ')+'B else '''' end)'

	set @i=@i+1

end

exec ('select A, B='+@sql+' from (select *,i=(select count(1) from #T where A=a.A and B<=a.B) from #T a) t group by A')

/*

A    B

---- -----------------------------

pro1 eeeee,qqqqq,uuuuu,wwwww,yyyyy -->如要按顺序,请生成唯一的标识列：where A=a.A and ID<=a.ID

pro2 rrrrr,ttttt

*/



--> 2005

select A, B=(stuff((select ','+B from #T where A=a.A for xml path('')),1,1,'')) from #T a group by A

/*

A    B

---- -----------------------------

pro1 qqqqq,wwwww,eeeee,yyyyy,uuuuu

pro2 rrrrr,ttttt

*/

/******************************************/

/*回复：代码20080518002 总：00000000020    */

/*主题：合并字段                          */

/*作者：二等草                             */

/******************************************/

set nocount on

/************例子数据 begin****************/

create table tb(A  varchar(10), B  varchar(10))

insert tb select 'pro1',      'qqqqq'  

insert tb select 'pro1',      'wwwww'  

insert tb select 'pro1',      'eeeee'  

insert tb select 'pro2',      'rrrrr' 

insert tb select 'pro2',      'ttttt'  

insert tb select 'pro1',      'yyyyy'  

insert tb select 'pro1',      'uuuuu'  

go

/************例子数据 end******************/



/************代码     begin***************/

create function getstr(@id varchar(10))

returns varchar(50)

as

begin

 declare @s varchar(50)

 select @s = isnull(@s+',','')+b from tb where a=@id

 return @s

end

go

select a,dbo.getstr(a) from tb group by a

go



/************代码     end*****************/

a                                                             

---------- -------------------------------------------------- 

pro1       qqqqq,wwwww,eeeee,yyyyy,uuuuu

pro2       rrrrr,ttttt



/************结果     begin***************/



/************清除*************************/

drop function getstr

go

drop table tb