作者:若v0丷會飛的獨角獸 | 来源:互联网 | 2023-05-17 03:12
求助:一个程序已经在运行了,再双击这个可执行程序,不会运行两个这样的程序,只是跳出先前程序的窗口。请问如何实现!请各位高手指教。
4 个解决方案
program YiLiao
{$R *.res}
var
Window1 : HWND;
begin
Application.Initialize;
Window1 := FindWindow(nil,'title'); //title为project --> Options --> Application页 -->title的值
if Window1 = 0 then
begin
Application.Title := 'title';
Application.CreateForm(TMainForm, MainForm);
Application.CreateForm(TAboutForm, AboutForm);
Application.Run;
end
else
begin
Application.Terminate ;
ShowWindow( Window1, SW_SHOWDEFAULT );
end;
end.
Window1 := FindWindow(nil,'title'); //title为project --> Options --> Application页 -->title的值
--------------------------------------------------
title会不会不是唯一的? 要是不是唯一的会不会显示别的程序的窗口,想运行的程序一个都没有打开?
工程文件中:
Application.Initialize;
hmutex:=createmutex(nil,false,'project1');
ret:=getlasterror;
if ret<>error_already_exists then
begin
//正常初始化的部分
end
else
begin
//报错
end;
这个是使用互斥体的例子.要引用shellapi.
把下面的代码存为MultInst.pas,然后在工程中加入它就可以了
注意:把STR_UNIQUE设置为你的字符串,可以生成一个GUDI,每个软件使用不同的GUID就不会有错
//==============================================================================
// Unit Name: MultInst
// Author : ysai
// Date : 2003-05-20
// Purpose : 解决应用程序多实例问题
// History :
//==============================================================================
//==============================================================================
// 工作流程
// 程序运行先取代原有向所有消息处理过程,然后广播一个消息.
// 如果有其它实例运行,收到广播消息会回发消息给发送程序,并传回它自己的句柄
// 发送程序接收到此消息,激活收到消息的程序,然后关闭自己
//==============================================================================
unit MultInst;
interface
uses
Windows ,Messages, SysUtils, Classes, Forms;
implementation
const
STR_UNIQUE = '{1E1084F3-A7FA-49B0-BEF4-CBF1F5451962}';
MI_ADDMESSAGE = 0; //新增一条消息
MI_ACTIVEAPP = 1; //激活应用程序
MI_GETHANDLE = 2; //取得句柄
var
iMessageID : Integer;
OldWProc : TFNWndProc;
MutHandle : THandle;
BSMRecipients : DWORD;
function NewWndProc(Handle: HWND; Msg: Integer; wParam, lParam: Longint):
Longint; stdcall;
begin
Result := 0;
if Msg = iMessageID then
begin
case wParam of
MI_ACTIVEAPP: //激活应用程序
if lParam<>0 then
begin
//收到消息的激活前一个实例
//为什么要在另一个程序中激活?
//因为在同一个进程中SetForegroundWindow并不能把窗体提到最前
if IsIconic(lParam) then
OpenIcon(lParam);
ShowWindow(lParam,SW_SHOW);
SetForegroundWindow(lParam);
//终止本实例
Application.Terminate;
end;
MI_GETHANDLE: //取得程序句柄
begin
PostMessage(HWND(lParam), iMessageID, MI_ACTIVEAPP,
Screen.ActiveForm.Handle);
end;
end;
end
else
Result := CallWindowProc(OldWProc, Handle, Msg, wParam, lParam);
end;
procedure InitInstance;
begin
//取代应用程序的消息处理
OldWProc := TFNWndProc(SetWindowLong(Application.Handle, GWL_WNDPROC,
Longint(@NewWndProc)));
//打开互斥对象
MutHandle := OpenMutex(MUTEX_ALL_ACCESS, False, STR_UNIQUE);
if MutHandle = 0 then
begin
//建立互斥对象
MutHandle := CreateMutex(nil, False, STR_UNIQUE);
end
else begin
Application.ShowMainForm := False;
//已经有程序实例,广播消息取得实例句柄
BSMRecipients := BSM_APPLICATIONS;
BroadCastSystemMessage(BSF_IGNORECURRENTTASK or BSF_POSTMESSAGE,
@BSMRecipients, iMessageID, MI_GETHANDLE,Application.Handle);
end;
end;
initialization
//注册消息
iMessageID := RegisterWindowMessage(STR_UNIQUE);
InitInstance;
finalization
//还原消息处理过程
if OldWProc <> Nil then
SetWindowLong(Application.Handle, GWL_WNDPROC, LongInt(OldWProc));
//关闭互斥对象
if MutHandle <> 0 then CloseHandle(MutHandle);
end.